CMakeLists.txt

file(GLOB _SRCS "*.h" "*.cc")
list(REMOVE_ITEM _SRCS
  ${CMAKE_CURRENT_SOURCE_DIR}/hungarian_test.cc
  ${CMAKE_CURRENT_SOURCE_DIR}/hungarian_test.h
  )

set(NAME ${PROJECT_NAME}_algorithms)

# Will be merge in libortools.so
#add_library(${NAME} STATIC ${_SRCS})
add_library(${NAME} OBJECT ${_SRCS})
set_target_properties(${NAME} PROPERTIES
  CXX_STANDARD 11
  CXX_STANDARD_REQUIRED ON
  CXX_EXTENSIONS OFF
  POSITION_INDEPENDENT_CODE ON
  )
# CMake < 3.12: CMakeError: Object library may not link to anything.
#target_link_libraries(${NAME} PRIVATE
#  absl::memory absl::str_format
#  gflags::gflags glog::glog
#  protobuf::libprotobuf
#  ${PROJECT_NAME}::proto)
target_include_directories(${NAME} PRIVATE
  ${PROJECT_SOURCE_DIR}
  ${PROJECT_BINARY_DIR}
  $<TARGET_PROPERTY:absl::memory,INTERFACE_INCLUDE_DIRECTORIES>
  $<TARGET_PROPERTY:absl::str_format,INTERFACE_INCLUDE_DIRECTORIES>
  $<TARGET_PROPERTY:gflags::gflags,INTERFACE_INCLUDE_DIRECTORIES>
  $<TARGET_PROPERTY:glog::glog,INTERFACE_INCLUDE_DIRECTORIES>
  $<TARGET_PROPERTY:protobuf::libprotobuf,INTERFACE_INCLUDE_DIRECTORIES>
  $<TARGET_PROPERTY:${PROJECT_NAME}::proto,INTERFACE_INCLUDE_DIRECTORIES>)
target_compile_options(${NAME} PRIVATE
  $<TARGET_PROPERTY:absl::memory,INTERFACE_COMPILE_OPTIONS>
  $<TARGET_PROPERTY:absl::str_format,INTERFACE_COMPILE_OPTIONS>
  $<TARGET_PROPERTY:gflags::gflags,INTERFACE_COMPILE_OPTIONS>
  $<TARGET_PROPERTY:glog::glog,INTERFACE_COMPILE_OPTIONS>
  $<TARGET_PROPERTY:protobuf::libprotobuf,INTERFACE_COMPILE_OPTIONS>
  $<TARGET_PROPERTY:${PROJECT_NAME}::proto,INTERFACE_COMPILE_OPTIONS>
  )
target_compile_definitions(${NAME} PRIVATE
  $<TARGET_PROPERTY:absl::memory,INTERFACE_COMPILE_DEFINITIONS>
  $<TARGET_PROPERTY:absl::str_format,INTERFACE_COMPILE_DEFINITIONS>
  $<TARGET_PROPERTY:gflags::gflags,INTERFACE_COMPILE_DEFINITIONS>
  $<TARGET_PROPERTY:glog::glog,INTERFACE_COMPILE_DEFINITIONS>
  $<TARGET_PROPERTY:protobuf::libprotobuf,INTERFACE_COMPILE_DEFINITIONS>
  $<TARGET_PROPERTY:${PROJECT_NAME}::proto,INTERFACE_COMPILE_DEFINITIONS>
  )
add_dependencies(${NAME}
  absl::memory absl::str_format
  gflags::gflags glog::glog
  protobuf::libprotobuf
  ${PROJECT_NAME}::proto)
add_library(${PROJECT_NAME}::algorithms ALIAS ${NAME})