build.gradle

buildscript {
    repositories {
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "com.gradle.publish:plugin-publish-plugin:0.12.0"
    }
}

plugins {
    //id "com.jfrog.bintray" version "1.8.5"
    id "java-gradle-plugin"
}

group = "de.cgoit.gradle.elasticsearch"
archivesBaseName = "gradle-elasticsearch-plugin"
version = "0.3.1-SNAPSHOT"

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: "com.gradle.plugin-publish"

compileGroovy {
    sourceCompatibility = '1.8'
    targetCompatibility = '1.8'
}

repositories {
    mavenCentral()
}

dependencies {
    compile gradleApi()
    compile localGroovy()
    compile "de.undercouch:gradle-download-task:4.0.4"
    compile "org.apache.httpcomponents:fluent-hc:4.5.12"
    compile "com.kstruct:gethostname4j:0.0.3"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    archiveClassifier = 'sources'
}

task javadocJar(type: Jar) {
    archiveClassifier = 'javadoc'
    from javadoc
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    useGpgCmd()
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://s01.oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'Gradle Elasticsearch Plugin'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'A gradle plugin for starting and stopping Elasticsearch during integration tests'
                url 'https://github.com/cgoIT/gradle-elasticsearch-plugin'

                scm {
                    connection 'scm:git:https://github.com/cgoIT/gradle-elasticsearch-plugin.git'
                    developerConnection 'scm:git:https://github.com/cgoIT/gradle-elasticsearch-plugin.git'
                    url 'https://github.com/cgoIT/gradle-elasticsearch-plugin'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'cgoIT'
                        name 'Carsten Goetzinger'
                        email 'carsten@cgo-it.de'
                    }
                    developer {
                        id 'dakotamaker'
                        name 'Dakota Maker'
                    }
                }
            }
        }
    }
}