build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'com.rikonardo.papermake' version '1.0.6'
}

group = 'cx.rain.mc.morepotions'
version = '1.0.2'
archivesBaseName = 'more-potions'

sourceCompatibility = JavaVersion.toVersion(21)
targetCompatibility = JavaVersion.toVersion(21)

allprojects {
    apply plugin: 'java'

    repositories {
        mavenCentral()
        maven {
            name = 'spigotmc-repo'
            url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
        }
        maven {
            name = 'CodeMC NMS repo'
            url = 'https://repo.codemc.io/repository/nms/'
        }
        maven {
            name = 'sonatype'
            url = 'https://oss.sonatype.org/content/groups/public/'
        }
    }

    dependencies {
        compileOnly 'org.spigotmc:spigot-api:1.21.1-R0.1-SNAPSHOT'
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

jar.dependsOn(shadowJar)

shadowJar {
    mergeServiceFiles()
}

dependencies {
    implementation project(':Compat')

    var mcmmo = findProject(':Compat:mcMMO')
    if (mcmmo != null) {
        implementation mcmmo
    }
}